s6cderi3.F File Reference

#include "implicit_f.inc"
#include "mvsiz_p.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	s6cderi3 (nel, vol, geo, vzl, ngl, deltax, det, x1, x2, x3, x4, x5, x6, y1, y2, y3, y4, y5, y6, z1, z2, z3, z4, z5, z6)

Function/Subroutine Documentation

s6cderi3()

subroutine s6cderi3	(	integer	nel,
			vol,
			geo,
			vzl,
		integer, dimension(*)	ngl,
			deltax,
			det,
			x1,
			x2,
			x3,
			x4,
			x5,
			x6,
			y1,
			y2,
			y3,
			y4,
			y5,
			y6,
			z1,
			z2,
			z3,
			z4,
			z5,
			z6 )

Definition at line 34 of file s6cderi3.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL,NGL(*)
      my_real
     .   vol(*), geo(npropg,*),vzl(*), deltax(*), det(*)
      my_real 
     .     x1(*), x2(*), x3(*), x4(*), x5(*), x6(*), 
     .     y1(*), y2(*), y3(*), y4(*), y5(*), y6(*), 
     .     z1(*), z2(*), z3(*), z4(*), z5(*), z6(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, NFAC
      my_real
     .   x21(mvsiz) , x31(mvsiz) , x41(mvsiz) , x54(mvsiz),x64(mvsiz),
     .   y21(mvsiz) , y31(mvsiz) , y41(mvsiz) , y54(mvsiz),y64(mvsiz),
     .   z21(mvsiz) , z31(mvsiz) , z41(mvsiz) , z54(mvsiz),z64(mvsiz),
     .   jac1(mvsiz), jac2(mvsiz) ,jac3(mvsiz), 
     .   jac4(mvsiz), jac5(mvsiz) ,jac6(mvsiz), 
     .   jac7(mvsiz), jac8(mvsiz) ,jac9(mvsiz), 
     .   jac_59_68(mvsiz), jac_67_49(mvsiz), jac_48_57(mvsiz)
 
      my_real
     .   xioff(mvsiz), aream(mvsiz),
     .   atest(mvsiz), area(6,mvsiz)
 
C=======================================================================
 
      DO i=1,nel
        x21(i)=x2(i)-x1(i)
        x31(i)=x3(i)-x1(i)
        x41(i)=x4(i)-x1(i)
        x54(i)=x5(i)-x4(i)
        x64(i)=x6(i)-x4(i)
C
        y21(i)=y2(i)-y1(i)
        y31(i)=y3(i)-y1(i)
        y41(i)=y4(i)-y1(i)
        y54(i)=y5(i)-y4(i)
        y64(i)=y6(i)-y4(i)
C
        z21(i)=z2(i)-z1(i)
        z31(i)=z3(i)-z1(i)
        z41(i)=z4(i)-z1(i)
        z54(i)=z5(i)-z4(i)
        z64(i)=z6(i)-z4(i)
      ENDDO
 
      DO i=1,nel
C-------ri.xi---->ksi--------
        jac1(i)=x21(i)+x54(i)
        jac2(i)=y21(i)+y54(i)
        jac3(i)=z21(i)+z54(i)
      ENDDO
 
      DO i=1,nel
C-------si.xi--->eta--------
        jac4(i)=x31(i)+x64(i)
        jac5(i)=y31(i)+y64(i)
        jac6(i)=z31(i)+z64(i)
C-------ti.xi----zeta-------
        jac7(i)=third*(x41(i)+x5(i)-x2(i)+x6(i)-x3(i))
        jac8(i)=third*(y41(i)+y5(i)-y2(i)+y6(i)-y3(i))
        jac9(i)=third*(z41(i)+z5(i)-z2(i)+z6(i)-z3(i))
      ENDDO
 
      DO i=1,nel
        jac_59_68(i)=jac5(i)*jac9(i)-jac6(i)*jac8(i)
        jac_67_49(i)=jac6(i)*jac7(i)-jac4(i)*jac9(i)
        jac_48_57(i)=jac4(i)*jac8(i)-jac5(i)*jac7(i)
      ENDDO
C
      DO i=1,nel
        det(i)=one_over_8*(jac1(i)*jac_59_68(i)+jac2(i)*jac_67_49(i)+jac3(i)*jac_48_57(i))
        vol(i)=det(i)
      ENDDO
C
      DO i=1,nel
        IF(det(i)>zero) cycle
        CALL ancmsg(msgid=245,
     .              msgtype=msgerror,
     .              anmode=aninfo,
     .              i1=ngl(i))
      ENDDO
 
      DO i=1,nel
         vzl(i) = fourth*(jac9(i)*(x54(i)*y64(i)-x21(i)*y31(i)-x64(i)*y54(i)+x31(i)*y21(i))
     .                   -jac8(i)*(x54(i)*z64(i)+x31(i)*z21(i)-x21(i)*z31(i)-x64(i)*z54(i))
     .                   +jac7(i)*(y54(i)*z64(i)+y31(i)*z21(i)-y21(i)*z31(i)-y64(i)*z54(i)))
C
      ENDDO
      DO i=1,nel
        xioff(i)=one
        aream(i)=zero
      ENDDO
C
      CALL slen(x1,x2,x5,x4,y1,y2,y4,y5,z1,z2,z5,z4,1, area, aream)
      CALL slen(x2,x5,x6,x3,y2,y5,y6,y3,z2,z5,z6,z3,2, area, aream)
      CALL slen(x1,x4,x6,x3,y1,y4,y6,y3,z1,z4,z6,z3,3, area, aream)
      CALL slen(x1,x2,x3,x3,y1,y2,y3,y3,z1,z2,z3,z3,4, area, aream)
      CALL slen(x4,x5,x6,x6,y4,y5,y6,y6,z4,z5,z6,z6,5, area, aream)
C
      DO i=1,nel
        atest(i)=em4*aream(i)
        nfac=0
        IF(area(1,i)<atest(i)) nfac=nfac+1
        IF(area(2,i)<atest(i)) nfac=nfac+1
        IF(area(3,i)<atest(i)) nfac=nfac+1
        IF(area(4,i)<atest(i)) nfac=nfac+1
        IF(area(5,i)<atest(i)) nfac=nfac+1
        IF(nfac>=2) xioff(i)=ep03
      ENDDO
      DO i=1,nel
         deltax(i)=four*det(i)*xioff(i)/sqrt(aream(i))
      ENDDO
C---
      RETURN