zgemqr.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	zgemqr (side, trans, m, n, k, a, lda, t, tsize, c, ldc, work, lwork, info)
	ZGEMQR

Function/Subroutine Documentation

zgemqr()

subroutine zgemqr	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	k,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	t,
		integer	tsize,
		complex*16, dimension( ldc, * )	c,
		integer	ldc,
		complex*16, dimension( * )	work,
		integer	lwork,
		integer	info )

ZGEMQR

Purpose:

!>
!> ZGEMQR overwrites the general real M-by-N matrix C with
!>
!>                      SIDE = 'L'     SIDE = 'R'
!>      TRANS = 'N':      Q * C          C * Q
!>      TRANS = 'T':      Q**H * C       C * Q**H
!>
!> where Q is a complex unitary matrix defined as the product
!> of blocked elementary reflectors computed by tall skinny
!> QR factorization (ZGEQR)
!>
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': apply Q or Q**H from the Left; !> = 'R': apply Q or Q**H from the Right. !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> = 'N': No transpose, apply Q; !> = 'C': Conjugate transpose, apply Q**H. !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >=0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. N >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines !> the matrix Q. !> If SIDE = 'L', M >= K >= 0; !> if SIDE = 'R', N >= K >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,K) !> Part of the data structure to represent Q as returned by ZGEQR. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. !> If SIDE = 'L', LDA >= max(1,M); !> if SIDE = 'R', LDA >= max(1,N). !>
[in]	T	!> T is COMPLEX*16 array, dimension (MAX(5,TSIZE)). !> Part of the data structure to represent Q as returned by ZGEQR. !>
[in]	TSIZE	!> TSIZE is INTEGER !> The dimension of the array T. TSIZE >= 5. !>
[in,out]	C	!> C is COMPLEX*16 array, dimension (LDC,N) !> On entry, the M-by-N matrix C. !> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK)) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> If LWORK = -1, then a workspace query is assumed. The routine !> only calculates the size of the WORK array, returns this !> value as WORK(1), and no error message related to WORK !> is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details

!>
!> These details are particular for this LAPACK implementation. Users should not 
!> take them for granted. These details may change in the future, and are not likely
!> true for another LAPACK implementation. These details are relevant if one wants
!> to try to understand the code. They are not part of the interface.
!>
!> In this version,
!>
!>          T(2): row block size (MB)
!>          T(3): column block size (NB)
!>          T(6:TSIZE): data structure needed for Q, computed by
!>                           ZLATSQR or ZGEQRT
!>
!>  Depending on the matrix dimensions M and N, and row and column
!>  block sizes MB and NB returned by ILAENV, ZGEQR will use either
!>  ZLATSQR (if the matrix is tall-and-skinny) or ZGEQRT to compute
!>  the QR factorization.
!>  This version of ZGEMQR will use either ZLAMTSQR or ZGEMQRT to
!>  multiply matrix Q by another matrix.
!>  Further Details in ZLAMTSQR or ZGEMQRT.
!>
!> 

Definition at line 170 of file zgemqr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, LDA, M, N, K, TSIZE, LWORK, LDC
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, RIGHT, TRAN, NOTRAN, LQUERY
      INTEGER            MB, NB, LW, NBLCKS, MN
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemqrt, zlamtsqr, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          int, max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      lquery  = lwork.EQ.-1
      notran  = lsame( trans, 'N' )
      tran    = lsame( trans, 'C' )
      left    = lsame( side, 'L' )
      right   = lsame( side, 'R' )
*
      mb = int( t( 2 ) )
      nb = int( t( 3 ) )
      IF( left ) THEN
        lw = n * nb
        mn = m
      ELSE
        lw = mb * nb
        mn = n
      END IF
*
      IF( ( mb.GT.k ) .AND. ( mn.GT.k ) ) THEN
        IF( mod( mn - k, mb - k ).EQ.0 ) THEN
          nblcks = ( mn - k ) / ( mb - k )
        ELSE
          nblcks = ( mn - k ) / ( mb - k ) + 1
        END IF
      ELSE
        nblcks = 1
      END IF
*
      info = 0
      IF( .NOT.left .AND. .NOT.right ) THEN
        info = -1
      ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
        info = -2
      ELSE IF( m.LT.0 ) THEN
        info = -3
      ELSE IF( n.LT.0 ) THEN
        info = -4
      ELSE IF( k.LT.0 .OR. k.GT.mn ) THEN
        info = -5
      ELSE IF( lda.LT.max( 1, mn ) ) THEN
        info = -7
      ELSE IF( tsize.LT.5 ) THEN
        info = -9
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
        info = -11
      ELSE IF( ( lwork.LT.max( 1, lw ) ) .AND. ( .NOT.lquery ) ) THEN
        info = -13
      END IF
*
      IF( info.EQ.0 ) THEN
        work( 1 ) = lw
      END IF
*
      IF( info.NE.0 ) THEN
        CALL xerbla( 'ZGEMQR', -info )
        RETURN
      ELSE IF( lquery ) THEN
        RETURN
      END IF
*
*     Quick return if possible
*
      IF( min( m, n, k ).EQ.0 ) THEN
        RETURN
      END IF
*
      IF( ( left .AND. m.LE.k ) .OR. ( right .AND. n.LE.k )
     $     .OR. ( mb.LE.k ) .OR. ( mb.GE.max( m, n, k ) ) ) THEN
        CALL zgemqrt( side, trans, m, n, k, nb, a, lda, t( 6 ),
     $                nb, c, ldc, work, info )
      ELSE
        CALL zlamtsqr( side, trans, m, n, k, mb, nb, a, lda, t( 6 ),
     $                 nb, c, ldc, work, lwork, info )
      END IF
*
      work( 1 ) = lw
*
      RETURN
*
*     End of ZGEMQR
*