hm_read_table1_1.F File Reference

#include "implicit_f.inc"
#include "scr17_c.inc"
#include "units_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_table1_1 (ntable1, ntable, table, nfunct, npc, pld, l, nom_opt, unitab, lsubmodel)

Function/Subroutine Documentation

hm_read_table1_1()

subroutine hm_read_table1_1	(	integer	ntable1,
		integer	ntable,
		type(ttable), dimension(*)	table,
		integer	nfunct,
		integer, dimension(*)	npc,
			pld,
		integer	l,
		integer, dimension(lnopt1,*)	nom_opt,
		type(unit_type_), intent(in)	unitab,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel )

Definition at line 40 of file hm_read_table1_1.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE table_mod
      USE message_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE unitab_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharfield
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NTABLE, NTABLE1,L,NFUNCT,NPC(*)
      my_real pld(*)
      TYPE(TTABLE) TABLE(*)
      INTEGER NOM_OPT(LNOPT1,*)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(UNIT_TYPE_), INTENT(IN) :: UNITAB
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr17_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER ITYPE, IBID, NFUNCT0
      INTEGER I, J, K, II, N, NDIM, NX(4), NY,
     .        JREC, NPTS, STAT, LL,NPT,IPT
      INTEGER IERROR, NF, IDFUNC, NP
      my_real bid, f5(5), time, funct
      CHARACTER(LEN=NCHARTITLE) :: TITR,TITR1
      CHARACTER MESS*40
      CHARACTER(LEN=NCHARFIELD) :: KEY
      DATA mess/' FUNCTION & TABLE DEFINITION            '/
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE
C======================================================================|
      is_encrypted = .false.
      is_available = .false.
 
      CALL hm_option_start('/TABLE/1')
      DO i=1,ntable1 
 
 
       CALL hm_option_read_key(lsubmodel, 
     .                         option_titr = titr, 
     .                         option_id = ll) 
      CALL hm_option_is_encrypted(is_encrypted)
C-----------------------------------------------
       nx(1) = 0
       nx(2) = 0
       nx(3) = 0
       nx(4) = 0
 
       CALL hm_get_intv('ORDER', ndim, is_available, lsubmodel)
       IF(ndim/=1.AND.ndim/=2.AND.ndim/=3.AND.ndim/=4)THEN
         CALL ancmsg(msgid=777,
     .               msgtype=msgerror,
     .               anmode=aninfo_blind_1,
     .               i1=ll,
     .               c1=titr)
       END IF
       CALL hm_get_intv('curverows', npt, is_available, lsubmodel) !size of X
 
       IF(ndim==1)THEN
          l=l+1
          npts=npt
          npc(nfunct+l+1)=ll                                       
          npc(l+1)=npc(l)                                          
 
          npts=0                                                   
c read abscissa values      
          DO ipt = 1, npt
             CALL hm_get_float_array_index('table2darray',time,2*ipt-1,is_available,lsubmodel,unitab)
c read ordinate values          
             CALL hm_get_float_array_index('table2darray',funct,2*ipt,is_available,lsubmodel, unitab) 
             npts=npts+1                                              
             pld(npc(l+1))=time
             IF(npts > 1 .AND. pld(npc(l+1)) <= pld(npc(l+1)-2))THEN  
                 CALL ancmsg(msgid=156,
     .                       msgtype=msgerror,
     .                       anmode=aninfo_blind_1,
     .                       i1=ll,
     .                       c1=titr1,
     .                       i2=npts,
     .                       i3=npts-1)
             ENDIF                                                    
             npc(l+1)=npc(l+1)+1                                      
             pld(npc(l+1))=funct                                      
             npc(l+1)=npc(l+1)+1                                      
          ENDDO ! IPT
 
C         build table structure
          table(l)%NOTABLE=ll
          table(l)%NDIM =1
          ALLOCATE(table(l)%X(1),stat=stat)
          IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                               msgtype=msgerror,
     .                         c1='TABLE')
          ALLOCATE(table(l)%X(1)%VALUES(npts),stat=stat)
          IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                               msgtype=msgerror,
     .                         c1='TABLE')
 
          ALLOCATE(table(l)%Y,stat=stat)
          IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                               msgtype=msgerror,
     .                         c1='TABLE')
          ALLOCATE(table(l)%Y%VALUES(npts),stat=stat)
          IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                               msgtype=msgerror,
     .                         c1='TABLE')
 
          DO n=1,npts
            table(l)%X(1)%VALUES(n)=pld(npc(l)+2*n-2)
            table(l)%Y%VALUES(n)   =pld(npc(l)+2*n-1)
          END DO
C
          IF (is_encrypted)THEN                                     
            WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'     
          ELSE     
            WRITE(iout,2100) table(l)%NOTABLE, table(l)%NDIM
            DO k=1,table(l)%NDIM
              nx(k)=SIZE( table(l)%X(k)%VALUES )
              WRITE(iout,2200) k
              WRITE(iout,2250) (table(l)%X(k)%VALUES(n),n=1,nx(k))
            END DO
            ny=SIZE(table(l)%Y%VALUES)
            WRITE(iout,2300)
            WRITE(iout,2350) (table(l)%Y%VALUES(n),n=1,ny)
          END IF
 
        endif!(NDIM==1)
       ENDDO !I=1,NTABLE0 
  
      RETURN
C-----------------------------------------------------------------
2000  FORMAT(//
     .        '    TABLES'/
     .        '    ------'/
     .        '    NUMBER OF TABLES . . . . . . . . . . =',i10/)
2100  FORMAT(/'    TABLE ID . . . . . . . . . . . . . . =',i10/
     .        '    NUMBER OF PARAMETERS . . . . . . . . =',i10/)
2200  FORMAT(/'    VALUES FOR PARAMETER NUMBER. . . . . .',i4,':'/)
2250  FORMAT((3x,5(1x,g20.13))/)
2300  FORMAT(/'    ORDINATE VALUES . . . . . . . . . . . :'/)
2350  FORMAT((3x,5(1x,g20.13))/)