nasg.F File Reference

#include "implicit_f.inc"
#include "comlock.inc"
#include "param_c.inc"
#include "com04_c.inc"
#include "com06_c.inc"
#include "com08_c.inc"
#include "vect01_c.inc"
#include "scr06_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	nasg (iflag, nel, pm, off, eint, mu, espe, dvol, vnew, mat, psh, pnew, dpdm, dpde)

Function/Subroutine Documentation

nasg()

subroutine nasg	(	integer	iflag,
		integer	nel,
			pm,
			off,
			eint,
			mu,
			espe,
			dvol,
			vnew,
		integer, dimension(nel)	mat,
		dimension(nel), intent(inout)	psh,
			pnew,
			dpdm,
			dpde )

Definition at line 28 of file nasg.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
C
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine contains numerical solving
C of NOBLE ABEL STIFFENED GAS EOS
C 2nd order integration in time
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "vect01_c.inc"
#include      "scr06_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER MAT(NEL), IFLAG, NEL
        my_real pm(npropm,nummat),
     .          off(nel)  ,eint(nel) ,mu(nel)   ,
     .          espe(nel) ,dvol(nel) ,
     .          vnew(nel) ,pnew(nel) ,dpdm(nel),
     .          dpde(nel)
        my_real, INTENT(INOUT) :: psh(nel)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER I, MX
        my_real :: p0,gamma,e0,aa,bb,pp,pstar, pc,v0
        my_real :: q,q_,cv,rho0,num,denom,unpmu,b,rho
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
 
        IF(iflag == 0) THEN
          mx         = mat(1)
          e0         = pm(23 ,mx)
          gamma      = pm(34 ,mx)
          p0         = pm(32 ,mx)
          psh(1:nel) = pm(88 ,mx)
          pstar      = pm(160,mx)
          q          = pm(35 ,mx)
          q_         = pm(36 ,mx)
          b          = pm(161,mx)
          cv         = pm(162,mx)
          rho0       = pm(1 , mx)
          DO i=1,nel
            unpmu   =  one+mu(i)
            denom   = (one-rho0*b*unpmu)
            num     = (espe(i)-rho0*q)
            pp      = (gamma-one)*unpmu*num/denom - gamma*pstar
            dpde(i) = (gamma-one)*unpmu / denom                                         !partial derivative
            dpdm(i) = (gamma-one)*num/denom/denom + dpde(i)*(pp+psh(i))/unpmu/unpmu     !total derivative
            pnew(i) = max(pp,-gamma*pstar)*off(i)   ! P(mu[n+1],E[n])
          ENDDO
 
        ELSEIF(iflag == 1) THEN
          mx         = mat(1)
          e0         = pm(23 ,mx)
          gamma      = pm(34 ,mx)
          p0         = pm(32 ,mx)
          psh(1:nel) = pm(88 ,mx)
          pstar      = pm(160,mx)
          q          = pm(35 ,mx)
          q_         = pm(36 ,mx)
          b          = pm(161,mx)
          cv         = pm(162,mx)
          rho0       = pm(1 , mx)
          DO i=1,nel
            eint(i) = eint(i) - half*dvol(i)*(pnew(i)+psh(i))
            unpmu   =  one+mu(i)
            rho     = unpmu*rho0
            v0      = vnew(i)*rho/rho0
            denom   = (vnew(i)/v0-rho0*b)
            aa      = (gamma-one)*(-rho0*q/denom)-gamma*pstar
            bb      = (gamma-one)/ denom
            dpde(i) = bb  !partial derivative
            pnew(i) = (aa+bb*eint(i)/v0)/(one+bb*dvol(i)/two/v0)   ! P(mu[n+1],E[n+1])
            pnew(i) = max(pnew(i),-gamma*pstar)*off(i)
          ENDDO
 
        ELSEIF(iflag == 2) THEN
          mx         = mat(1)
          e0         = pm(23 ,mx)
          gamma      = pm(34 ,mx)
          p0         = pm(32 ,mx)
          psh(1:nel) = pm(88 ,mx)
          pstar      = pm(160,mx)
          q          = pm(35 ,mx)
          q_         = pm(36 ,mx)
          b          = pm(161,mx)
          cv         = pm(162,mx)
          rho0       = pm(1 , mx)
          pc         = pm(37, mx)
          DO i=1, nel
            IF (vnew(i) > zero) THEN
              unpmu   =  one+mu(i)
              denom   = (one-rho0*b*unpmu)
              num     = (espe(i)-rho0*q)
              pnew(i) = -psh(i) +  (gamma-one)*unpmu*num/denom - gamma*pstar
              pnew(i) = max(pnew(i),max(pc, -gamma*pstar))*off(i)
              dpde(i) = (gamma-one)*unpmu / denom                                              !partial derivative
              dpdm(i) = (gamma-one)*num/denom/denom + dpde(i)*(pnew(i)+psh(i))/unpmu/unpmu     !total derivative
            ENDIF
          ENDDO
 
        ENDIF
C-----------------------------------------------
        RETURN