hm_read_sensors.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_sensors          ../starter/source/tools/sensor/hm_read_sensors.F
!||--- called by ------------------------------------------------------
!||    lectur                   ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_option_count          ../starter/source/devtools/hm_reader/hm_option_count.F
!||    hm_option_read_key       ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start          ../starter/source/devtools/hm_reader/hm_option_start.f
!||    read_sensor_acc          ../starter/source/tools/sensor/read_sensor_acc.F
!||    read_sensor_and          ../starter/source/tools/sensor/read_sensor_and.F
!||    read_sensor_contact      ../starter/source/tools/sensor/read_sensor_contact.F
!||    read_sensor_disp         ../starter/source/tools/sensor/read_sensor_disp.F
!||    read_sensor_dist_surf    ../starter/source/tools/sensor/read_sensor_dist_surf.F
!||    read_sensor_energy       ../starter/source/tools/sensor/read_sensor_energy.F
!||    read_sensor_gauge        ../starter/source/tools/sensor/read_sensor_gauge.F
!||    read_sensor_hic          ../starter/source/tools/sensor/read_sensor_hic.F
!||    read_sensor_nic          ../starter/source/tools/sensor/read_sensor_nic.F
!||    read_sensor_not          ../starter/source/tools/sensor/read_sensor_not.f
!||    read_sensor_or           ../starter/source/tools/sensor/read_sensor_or.F
!||    read_sensor_python       ../starter/source/tools/sensor/hm_read_sensor_python.F90
!||    read_sensor_rbody        ../starter/source/tools/sensor/read_sensor_rbody.F
!||    read_sensor_rwall        ../starter/source/tools/sensor/read_sensor_rwall.F
!||    read_sensor_sect         ../starter/source/tools/sensor/read_sensor_sect.F
!||    read_sensor_sens         ../starter/source/tools/sensor/read_sensor_sens.F
!||    read_sensor_temp         ../starter/source/tools/sensor/read_sensor_temp.F
!||    read_sensor_time         ../starter/source/tools/sensor/read_sensor_time.F
!||    read_sensor_user         ../starter/source/tools/sensor/read_sensor_user.F
!||    read_sensor_vel          ../starter/source/tools/sensor/read_sensor_vel.F
!||    read_sensor_work         ../starter/source/tools/sensor/read_sensor_work.F
!||    sensor_tab_init          ../starter/source/tools/sensor/sensor_tab_init.F
!||    udouble                  ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod       ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    read_sensor_python_mod   ../starter/source/tools/sensor/hm_read_sensor_python.f90
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||    surf_mod                 ../starter/share/modules1/surf_mod.F
!||====================================================================
      SUBROUTINE hm_read_sensors(PYTHON,
     .           SENSORS   ,LACCELM   ,ITABM1    ,IPART     ,LGAUGE    ,
     .           SUBSET    ,NSETS     ,IGRNOD    ,
     .           ISKWN     ,UNITAB    ,LSUBMODEL ,HM_NSENS  ,
     .           SENSOR_USER_STRUCT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE python_funct_mod
      USE my_alloc_mod  
      USE unitab_mod
      USE message_mod
      USE groupdef_mod
      USE inoutfile_mod
      USE surf_mod
      USE submodel_mod
      USE sensor_mod
      USE hm_option_read_mod
      USE read_sensor_python_mod, ONLY : read_sensor_python
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "scr17_c.inc"
#include      "com04_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(python_), intent(inout) :: PYTHON
      INTEGER ,INTENT(IN)  :: NSETS
      INTEGER ,INTENT(OUT) :: HM_NSENS
      INTEGER ,DIMENSION(*)   ,INTENT(IN) :: ITABM1
      INTEGER ,DIMENSION(3,*) ,INTENT(IN) :: LACCELM,LGAUGE
      INTEGER ,DIMENSION(LISKN,*)   ,INTENT(IN) :: ISKWN
      INTEGER ,DIMENSION(LIPART1,*) ,INTENT(IN) :: IPART
      TYPE (SENSORS_) ,INTENT(INOUT) ,TARGET   :: SENSORS
      TYPE (GROUP_)      ,DIMENSION(NGRNOD)    :: IGRNOD
      TYPE (SUBSET_)     ,DIMENSION(NSUBS)     :: SUBSET
      TYPE (SUBMODEL_DATA) ,DIMENSION(NSUBMOD) :: LSUBMODEL
      TYPE (UNIT_TYPE_)  ,INTENT(IN) ::UNITAB 
      TYPE(sensor_user_struct_) ,INTENT(INOUT) :: SENSOR_USER_STRUCT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER ISEN,IUNIT,IFLAGUNIT,NS,UNIT_ID,SENS_ID
      my_real :: BID
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER KEY*40,MESS*40
      INTEGER ,DIMENSION(:) ,ALLOCATABLE   :: SID
      TYPE(python_function), DIMENSION(:), ALLOCATABLE :: temp
      DATA mess/'SENSOR DEFINITION                       '/
C=======================================================================
c     Initialize sensor data structure
c---------------------------------------------
      CALL hm_option_count('/SENSOR', hm_nsens)
      CALL hm_option_count('/SENSOR/PYTHON', ns)
      IF(ns > 0) THEN
        call python_initialize(python_error)
        if(.not. allocated(python%functs)) then 
          allocate(python%functs(ns))
        else
          allocate(temp(python%nb_functs + ns))
          temp(1:python%nb_functs) = python%functs
          CALL move_alloc(from=temp,to=python%functs)
        endif
      END IF
      IF (hm_nsens > 0) THEN
        WRITE(istdo,'(A)')' .. SENSORS'
        WRITE (iout,'(///,A)')'          SENSORS'
        WRITE (iout,'(A/)')   '          -------'
      END IF
c---------------------------------------------
      IF (ALLOCATED(sensors%SENSOR_TAB)) DEALLOCATE(sensors%SENSOR_TAB)
      ALLOCATE(sensors%SENSOR_TAB(hm_nsens))
      CALL my_alloc (sid,hm_nsens)
      sensors%NSENSOR = hm_nsens
c
      CALL sensor_tab_init(sensors)
c
      CALL hm_option_start('/SENSOR')
c
c---------------------------------------------------
c
      DO isen = 1,hm_nsens
c            
        CALL hm_option_read_key(lsubmodel,
     .                          option_id   = sens_id,
     .                          option_titr = titr  ,
     .                          unit_id     = unit_id   ,
     .                          keyword2    = key   )
c--------------------------------------------------
c       CHECK IF UNIT_ID EXISTS
c--------------------------------------------------
        iflagunit = 0
        DO iunit=1,unitab%NUNITS
          IF (unitab%UNIT_ID(iunit) == unit_id) THEN
            iflagunit = 1
            EXIT
          ENDIF
        ENDDO
        IF (unit_id > 0 .AND. iflagunit == 0) THEN
          CALL ancmsg(msgid=659,anmode=aninfo,msgtype=msgerror,
     .                i2=unit_id,i1=sens_id,
     .                c1='SENSOR', c2='SENSOR', c3='TITR')                              
        ENDIF
c
        key = key(1:len_trim(key))
c-----------------------
        SELECT CASE(key)
c-----------------------
          CASE ('TIME' ,'TYPE0')
            CALL read_sensor_time(sensors%SENSOR_TAB(isen) ,sens_id  ,unitab   ,lsubmodel)  
c
          CASE ('ACCE' ,'TYPE1')
            CALL read_sensor_acc(sensors%SENSOR_TAB(isen) ,sens_id  ,titr     , 
     .           laccelm  ,unitab   ,lsubmodel)  
c
          CASE ('DIST' ,'TYPE2')
            CALL read_sensor_disp(sensors%SENSOR_TAB(isen) ,sens_id  ,
     .           itabm1   ,unitab   ,lsubmodel)   
c
          CASE ('SENS' ,'TYPE3')
            CALL read_sensor_sens(sensors%SENSOR_TAB(isen) ,sens_id  ,unitab   ,lsubmodel)
c
          CASE ('AND' ,'TYPE4')
            CALL read_sensor_and(sensors%SENSOR_TAB(isen) ,sens_id  ,unitab   ,lsubmodel)
c
          CASE ('OR' ,'TYPE5')
            CALL read_sensor_or(sensors%SENSOR_TAB(isen) ,sens_id  ,unitab   ,lsubmodel)
c
          CASE ('INTER' ,'TYPE6')
            CALL read_sensor_contact(sensors%SENSOR_TAB(isen) ,sens_id  ,titr     ,
     .           unitab   ,lsubmodel)
c
          CASE ('RWALL' ,'TYPE7')
            CALL read_sensor_rwall(sensors%SENSOR_TAB(isen) ,sens_id  ,titr     ,
     .           unitab   ,lsubmodel)
c
          CASE ('NOT' ,'TYPE8')
            CALL read_sensor_not(sensors%SENSOR_TAB(isen) ,sens_id  ,unitab   ,lsubmodel)
c
          CASE ('VEL' ,'TYPE9')
            CALL read_sensor_vel(sensors%SENSOR_TAB(isen) ,sens_id  ,
     .           itabm1   ,unitab   ,lsubmodel)   
c
          CASE ('GAUGE' ,'TYPE10')            
            CALL read_sensor_gauge(sensors%SENSOR_TAB(isen) ,sens_id  ,titr     ,
     .           lgauge   ,unitab   ,lsubmodel)
c
          CASE ('RBODY' ,'TYPE11')
            CALL read_sensor_rbody(sensors%SENSOR_TAB(isen) ,sens_id  ,titr     ,
     .           unitab   ,lsubmodel)
c
          CASE ('SECT' ,'TYPE12')
            CALL read_sensor_sect(sensors%SENSOR_TAB(isen) ,sens_id  ,titr     ,
     .           unitab   ,lsubmodel)
c
          CASE ('WORK' ,'TYPE13')
            CALL read_sensor_work(sensors%SENSOR_TAB(isen) ,sens_id  ,
     .           itabm1   ,unitab   ,lsubmodel)   
c
          CASE ('ENERGY' ,'TYPE14')
            CALL read_sensor_energy(sensors%SENSOR_TAB(isen) ,sens_id  ,titr     ,
     .           ipart   ,subset   ,unitab  ,lsubmodel)
c
          CASE ('DIST_SURF' ,'TYPE15')
            CALL read_sensor_dist_surf(sensors%SENSOR_TAB(isen) ,sens_id  ,
     .           itabm1   ,unitab   ,lsubmodel)   
c
          CASE ('HIC' ,'TYPE16')
            CALL read_sensor_hic(sensors%SENSOR_TAB(isen) ,sens_id  ,titr     , 
     .           laccelm  ,unitab   ,lsubmodel)  
c
          CASE ('TEMP')
            CALL read_sensor_temp(sensors%SENSOR_TAB(isen)  ,sens_id     ,titr     , 
     .           igrnod   ,unitab   ,lsubmodel)   
c
          CASE ('NIC_NIJ')
            CALL read_sensor_nic(
     .           sensors%SENSOR_TAB(isen)  ,sens_id    ,titr     ,iskwn    , 
     .           unitab      ,lsubmodel  )   
c
          CASE ('USER1' ,'USER2','USER3')
 
            sensors%SENSOR_TAB(isen)%TSTART = infinity
 
            CALL read_sensor_user(hm_nsens ,isen    ,titr,
     .           unitab    ,lsubmodel      ,key     ,unit_id ,sens_id ,
     .           sensors%SENSOR_TAB(isen),sensor_user_struct)
            sensors%SENSOR_TAB(isen)%SENS_ID = sens_id
          CASE('PYTHON')
            CALL read_sensor_python(python,
     .           sensors%SENSOR_TAB(isen)  ,sens_id    , lsubmodel  )   
 
          CASE DEFAULT
            CALL ancmsg(msgid=43, anmode=aninfo, msgtype=msgerror,
     .                  c2=key(1:len_trim(key)),
     .                  i1=sens_id,
     .                  c1=titr)        
        END SELECT 
c
        sensors%SENSOR_TAB(isen)%TITLE = titr
c-----------------
      END DO  ! NSENSOR
c-------------------------------------
c     Recherche des ID doubles  : activate this code when lecsen is removed
c-------------------------------------
      DO isen = 1,sensors%NSENSOR
        IF (sensors%SENSOR_TAB(isen)%SENS_ID > 0)  THEN
          sid(isen) = sensors%SENSOR_TAB(isen)%SENS_ID
        END IF
      END DO
      CALL udouble(sid,1,sensors%NSENSOR,mess,0,bid)
      DEALLOCATE(sid)
c-----------
      RETURN
      END